Merge pull request #1008 from debris/cmake_command

cmake fixes

CMakeLists.txt

@@ -88,7 +88,7 @@ function(createBuildInfo)
 	# Generate header file containing useful build information
 	add_custom_target(BuildInfo.h ALL
 		WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
-		COMMAND cmake -DETH_SOURCE_DIR="${CMAKE_SOURCE_DIR}" -DETH_DST_DIR="${CMAKE_BINARY_DIR}"
+		COMMAND ${CMAKE_COMMAND} -DETH_SOURCE_DIR="${CMAKE_SOURCE_DIR}" -DETH_DST_DIR="${CMAKE_BINARY_DIR}"
 			-DETH_BUILD_TYPE="${_cmake_build_type}" -DETH_BUILD_PLATFORM="${ETH_BUILD_PLATFORM}" 
 			-P "${ETH_SCRIPTS_DIR}/buildinfo.cmake"
 		)

cmake/EthUtils.cmake

@@ -0,0 +1,24 @@
+#
+# renames the file if it is different from its destination
+include(CMakeParseArguments)
+#
+macro(replace_if_different SOURCE DST)
+	set(extra_macro_args ${ARGN})
+	set(options CREATE)
+	set(one_value_args)
+	set(multi_value_args)
+	cmake_parse_arguments(REPLACE_IF_DIFFERENT "${options}" "${one_value_args}" "${multi_value_args}" "${extra_macro_args}")
+
+	if (REPLACE_IF_DIFFERENT_CREATE AND (NOT (EXISTS "${DST}")))
+		file(WRITE "${DST}" "")
+	endif()
+
+	execute_process(COMMAND ${CMAKE_COMMAND} -E compare_files "${SOURCE}" "${DST}" RESULT_VARIABLE DIFFERENT)
+
+	if (DIFFERENT)
+		execute_process(COMMAND ${CMAKE_COMMAND} -E rename "${SOURCE}" "${DST}")
+	else()
+		execute_process(COMMAND ${CMAKE_COMMAND} -E remove "${SOURCE}")
+	endif()
+endmacro()
+

cmake/scripts/buildinfo.cmake

@@ -19,7 +19,7 @@ endif()
 
 execute_process(
 	COMMAND git --git-dir=${ETH_SOURCE_DIR}/.git --work-tree=${ETH_SOURCE_DIR} rev-parse HEAD
-	OUTPUT_VARIABLE ETH_COMMIT_HASH OUTPUT_STRIP_TRAILING_WHITESPACE
+	OUTPUT_VARIABLE ETH_COMMIT_HASH OUTPUT_STRIP_TRAILING_WHITESPACE ERROR_QUIET
 ) 
 
 if (NOT ETH_COMMIT_HASH)
@@ -28,7 +28,7 @@ endif()
 
 execute_process(
 	COMMAND git --git-dir=${ETH_SOURCE_DIR}/.git --work-tree=${ETH_SOURCE_DIR} diff --shortstat	
-	OUTPUT_VARIABLE ETH_LOCAL_CHANGES OUTPUT_STRIP_TRAILING_WHITESPACE
+	OUTPUT_VARIABLE ETH_LOCAL_CHANGES OUTPUT_STRIP_TRAILING_WHITESPACE ERROR_QUIET
 )
 
 if (ETH_LOCAL_CHANGES)
@@ -41,21 +41,8 @@ set(INFILE "${ETH_SOURCE_DIR}/BuildInfo.h.in")
 set(TMPFILE "${ETH_DST_DIR}/BuildInfo.h.tmp")
 set(OUTFILE "${ETH_DST_DIR}/BuildInfo.h")
 
-# create outfile if it doesn't exist
-if (NOT (EXISTS "${OUTFILE}"))
-	execute_process(COMMAND touch "${OUTFILE}")
-endif()
-
 configure_file("${INFILE}" "${TMPFILE}")
 
-execute_process(
-	COMMAND diff "${OUTFILE}" "${TMPFILE}"
-	OUTPUT_VARIABLE ETH_FILE_OUTDATED
-)
-
-if (ETH_FILE_OUTDATED)
-	execute_process(COMMAND mv "${TMPFILE}" "${OUTFILE}")
-else()
-	execute_process(COMMAND rm "${TMPFILE}")
-endif()
+include("${ETH_SOURCE_DIR}/cmake/EthUtils.cmake")
+replace_if_different("${TMPFILE}" "${OUTFILE}" CREATE)
 

cmake/scripts/jsonrpcstub.cmake

@@ -0,0 +1,36 @@
+# generates JSONRPC Stub Server && Client
+#
+# this script expects
+# ETH_SOURCE_DIR - main CMAKE_SOURCE_DIR
+# ETH_SPEC_PATH
+# ETH_SERVER_DIR
+# ETH_CLIENT_DIR
+# ETH_SERVER_NAME
+# ETH_CLIENT_NAME
+# ETH_JSON_RPC_STUB
+# 
+# example usage:
+# cmake -DETH_SPEC_PATH=spec.json -DETH_SERVER_DIR=libweb3jsonrpc -DETH_CLIENT_DIR=test 
+# -DETH_SERVER_NAME=AbstractWebThreeStubServer -DETH_CLIENT_NAME=WebThreeStubClient -DETH_JSON_RPC_STUB=/usr/local/bin/jsonrpcstub
+
+# by default jsonrpcstub produces files in lowercase, we want to stick to this
+string(TOLOWER ${ETH_SERVER_NAME} ETH_SERVER_NAME_LOWER)
+string(TOLOWER ${ETH_CLIENT_NAME} ETH_CLIENT_NAME_LOWER)
+
+# setup names
+set(SERVER_TMPFILE "${ETH_SERVER_DIR}/${ETH_SERVER_NAME_LOWER}.h.tmp")
+set(SERVER_OUTFILE "${ETH_SERVER_DIR}/${ETH_SERVER_NAME_LOWER}.h")
+set(CLIENT_TMPFILE "${ETH_CLIENT_DIR}/${ETH_CLIENT_NAME_LOWER}.h.tmp")
+set(CLIENT_OUTFILE "${ETH_CLIENT_DIR}/${ETH_CLIENT_NAME_LOWER}.h")
+
+# create tmp files
+execute_process(
+	COMMAND ${ETH_JSON_RPC_STUB} ${ETH_SPEC_PATH} 
+		--cpp-server=${ETH_SERVER_NAME} --cpp-server-file=${SERVER_TMPFILE}
+		--cpp-client=${ETH_CLIENT_NAME} --cpp-client-file=${CLIENT_TMPFILE}
+)
+
+include("${ETH_SOURCE_DIR}/cmake/EthUtils.cmake")
+replace_if_different("${SERVER_TMPFILE}" "${SERVER_OUTFILE}")
+replace_if_different("${CLIENT_TMPFILE}" "${CLIENT_OUTFILE}")
+

libweb3jsonrpc/CMakeLists.txt

@@ -37,8 +37,11 @@ if (ETH_JSON_RPC_STUB)
 	add_custom_command(TARGET jsonrpcstub
 		POST_BUILD
 		WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
-		COMMAND ${ETH_JSON_RPC_STUB} spec.json --cpp-server=AbstractWebThreeStubServer --cpp-client=WebThreeStubClient 
-		COMMAND cmake -E rename webthreestubclient.h ../test/webthreestubclient.h
+		COMMAND ${CMAKE_COMMAND} -DETH_SPEC_PATH="${CMAKE_CURRENT_SOURCE_DIR}/spec.json" -DETH_SOURCE_DIR="${CMAKE_SOURCE_DIR}"
+			-DETH_SERVER_DIR="${CMAKE_CURRENT_SOURCE_DIR}" -DETH_CLIENT_DIR="${CMAKE_SOURCE_DIR}/test"
+			-DETH_SERVER_NAME=AbstractWebThreeStubServer -DETH_CLIENT_NAME=WebThreeStubClient
+			-DETH_JSON_RPC_STUB="${ETH_JSON_RPC_STUB}"
+			-P "${ETH_SCRIPTS_DIR}/jsonrpcstub.cmake"
 	)
 	add_dependencies(${EXECUTABLE} jsonrpcstub)
 endif()